PowerBI DAX 在矩阵分组区域内通用积累求和

什么是在矩阵分组区域内积累求和，先看一个例子吧。

对于左右两个图表，它们的规律是：

左图：在分组区域内，按照与当前元素的KPI从小到大，积累求和；
右图：在分组区域内，按照与当前元素的名称从小到大，积累求和。

这两种模式都非常常见，很多计算都会涉及这个问题。

这里给出了两种实现，一种是模型层计算；一种是视图层计算。

分别进行详解。我们先给出计算公式，再对重要技巧做出总结。

按KPI积累，模型层计算

DAX 公式如下：

代码语言：javascript复制

KPI.组内积累.按KPI大小.模型法 =
VAR _value = [KPI]
VAR _items =
    FILTER(
        CALCULATETABLE( SUMMARIZE( Customer , Customer[Industry] , Customer[Occupation] ) , ALL( Customer[Occupation] ) ),
        [KPI] <= _value
    )
RETURN CALCULATE( [KPI] , _items )

按KPI积累，视图层计算

DAX 公式如下：

代码语言：javascript复制

KPI.组内积累.按KPI大小.视图法 =
VAR _value_current = [KPI]
VAR _view =
CALCULATETABLE(
    ADDCOLUMNS(
        SUMMARIZE( Customer , Customer[Industry] , Customer[Occupation] ),
        "@KPI",
        [KPI]
    ),
    ALLSELECTED( )
)

VAR _group = VALUES( Customer[Industry] )

RETURN 
    SUMX( _group ,
        SUMX( _view , IF( [Industry] = EARLIER( Customer[Industry] ) && [@KPI] <= _value_current , [@KPI] ) )
    )

按名称积累，模型层计算

DAX 公式如下：

代码语言：javascript复制

KPI.组内积累.按元素名称.模型法 =
VAR _value = [KPI]
VAR _item  = SELECTEDVALUE( Customer[Occupation] , "座座座座" )
VAR _items =
    FILTER(
        CALCULATETABLE( SUMMARIZE( Customer , Customer[Industry] , Customer[Occupation] ) , ALL( Customer[Occupation] ) ),
        ISONORAFTER( [Occupation] , _item , DESC )
    )
RETURN CALCULATE( [KPI] , _items )

按名称积累，视图层计算

DAX 公式如下：

代码语言：javascript复制

KPI.组内积累.按元素名称.视图法 =
VAR _value_current = SELECTEDVALUE( Customer[Occupation] , "座座座座" )
VAR _view =
CALCULATETABLE(
    ADDCOLUMNS(
        SUMMARIZE( Customer , Customer[Industry] , Customer[Occupation] ),
        "@KPI",
        [KPI]
    ),
    ALLSELECTED( )
)

VAR _group = VALUES( Customer[Industry] )

RETURN
    SUMX( _group ,
        SUMX( _view , IF( [Industry] = EARLIER( Customer[Industry] ) && [Occupation] <= _value_current , [@KPI] ) )
    )