excelperfect
标签：VBA，类模块，用户窗体，文本框
在用户窗体中有许多个文本框，我想让这些文本框都不能输入字母。代替一个个对文本框进行处理，可以使用类模块来操作。
如图1所示，在用户窗体中有4个文本框，其中都不能输入字母。
图1
在VBE中，插入一个类模块，将其重命名为“clsObjHandler”，在代码窗口输入下面的代码：
代码语言：javascript复制Private WithEvents tbxCustomTextbox As MSForms.TextBox
Public Property Set Control(tbxNew As MSForms.TextBox)
Set tbxCustomTextbox = tbxNew
End Property
Private Sub tbxCustomTextbox_Change()
'用于显示哪个文本框被修改的消息框
MsgBox "正在输入的文本框: " & tbxCustomTextbox.Name
End Sub
Private Sub tbxCustomTextbox_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
Select Case KeyAscii
Case 46 To 57
Case Else
KeyAscii = 0
End Select
End Sub
Private Sub Class_Terminate()
Set tbxCustomTextbox = Nothing
End Sub打开用户窗体代码模块窗口，在其中输入下面的代码：
代码语言：javascript复制Dim colTbxs As Collection
Private Sub UserForm_Initialize()
Dim ctlLoop As MSForms.Control
Dim clsObject As clsObjHandler
'创建新集合来存储自定义文本框
Set colTbxs = New Collection
'遍历用户窗体中的控件
For Each ctlLoop In Me.Controls
'检查控件是否是文本框
If TypeOf ctlLoop Is MSForms.TextBox Then
'创建新实例
Set clsObject = New clsObjHandler
'设置为文本框
Set clsObject.Control = ctlLoop
'添加事件处理
colTbxs.Add clsObject
End If
Next ctlLoop
End Sub
Private Sub UserForm_Terminate()
Set colTbxs = Nothing
End Sub就这样！你可以举一反三，稍微修改代码或控件，运用到相似的情景中。
